Figure 1
|
This note discusses the ordinary diode demodulator as used in most AM radio receivers. It explains the nonlinear performance commonly observed by critical users and which is rarely discussed, especially in the introductory tutorial literature. The defects and their reasons are somewhat subtle and would complicate the typical introductory discussion of how the diode demodulator functions. They are usually ignored in the typical literature, possibly because the teachers and writers are ignorant of them. (Terman is an exception but then his teachings are directed toward professionals.) An ideal diode is used in this analysis; the forward voltage drop is zero, not a few tenths of a volt as might be encountered in the real world. This has been done so that the defects the author is bringing to the reader's attention are more clearly presented. The ill behavior of a silicon diode at low signal levels is commonly used as a scapegoat, a convenient (and incorrect) way of explaining the defects that will be discussed. The circuit performance using real-world diodes would of course be poorer than seen here, especially at low signal levels. This note uses Spice operating in the time-domain mode to generate the various waveforms. These waveforms have been generated using mathematical routines and so are textbook-ideal. The Spice netlists used for analysis are listed at the end of the paper. This encourages investigation of various tradeoffs when component values are altered or the topology is changed. Introduction - the slew rate problem The basic demodulator is shown in Figure 1. The component values are typical of many solid-state radios. By the simple operation of dividing the capacitor value by 100 and multiplying the resistor value by 100 they are typical of many vacuum-tube demodulators as well. The item now under discussion, the controlling factor, is the time-constant (the R and C product) of the load used for the demodulator. The depth of modulation for this introductory study has been fixed at 100% with a modulating frequency of 1000 Hz. The carrier frequency has been set to 25 kHz. This low carrier frequency is used to emphasize a couple of points. Later discussion will involve similar circuitry but with the carrier moved upward in frequency. The generator labeled "C" is the carrier source and the generator labeled "M" is the modulating signal. The modulation consists of a one-volt DC signal onto which has been added a one-volt peak sinusoid. The sum of those two components is then considered the modulating waveform. The "X" item is the multiplier used to generate the modulated signal which is then applied to the diode for demodulation. R1 and C1 form the diode load. |
|
The carrier to be modulated is shown in Figure 2. Unmodulated, it has an amplitude of 5 volts peak. For each millisecond on the X-axis scale we would see 25 sinusoidal cycles; the carrier frequency is 25 kHz. |
|
The modulating signal is shown in Figure 3.
Notice that this signal is composed of a steady DC component of 1 volt onto
which has been added a 1000 Hz sinusoid with an amplitude of 1 volt peak.
This total signal then modulates the carrier amplitude to a level of 100%.
|
|
Figure 4 shows the modulated carrier - the signal as transmitted or as
it would be delivered to the demodulator by the receiver's I.F. strip.
This signal was generated by multiplying the modulating wave by the
carrier wave.
The "idling" carrier level (no audio, just the steady DC component
to set carrier level) would be 5 volts peak.
With modulation (audio added to the steady DC component) we have an output
amplitude which goes from 0 to 10 volts peak over the course of the
modulating wave.
|
|
Figure 5 shows both what we would like to see at the
output of the ideal diode demodulator (the sinusoid shown in blue)
along with what we actually see (the black trace).
Each cycle of RF charges the capacitor via the diode.
The capacitor can only discharge through the resistor across it.
The capacitor charges right up to the peak value of the modulated wave.
It discharges in an exponential fashion toward ground at a very
clearly-defined rate (which is a function of the RC time-constant,
R1 and C1 in Figure 1).
|
|
Increasing the time constant of the load (parallel R1-C1) will reduce the level of the residual or "feedthrough" RF. It will also increase the negative-peak "diagonal clipping" as Terman calls it. Here we will call it slew-rate distortion. The residual RF is more obvious on the positive modulation peaks and the slew-rate problem is more evident on the negative modulation peaks. The slew-rate distortion becomes worse as the modulating rate increases, as the modulation level increases and as the time-constant increases. This latter situation will be reviewed later in this paper. The selectivity in the receiver's I.F. strip reduces the amplitude of the sidebands at the higher audio frequencies, reducing the modulation depth as seen by the demodulator, and so slew-rate distortion at those frequencies is rarely a problem in practice. The point to be noted here is that we have a slew-rate problem on the negative peaks (only), serious or not. |
|
When the carrier frequency is changed upward to 500 kHz, to more closely approximate a practical scenario, it would appear as shown in Figure 6. With a time period of 3 milliseconds as shown, it is obvious that individual cycles of the signal are not visible. |
|
Figure 7 illustrates the modulating signal, just as in the introduction.
It is still the steady DC component of 1 volt onto which has been
added a 1000 Hz sinusoid with a peak amplitude of 1 volt.
|
|
The modulated carrier is shown in Figure 8.
|
|
Using a 500 kHz carrier, what we would like to see at the
output of the ideal diode demodulator is shown in red
and what we will actually see is shown in green in Figure 9.
The amplitude of the residual RF is now lower because of the increased
carrier frequency.
|
|
|
|
The AC load problem The design of these demodulators as they are seen in typical radio receivers involves not only the parallel R-C load on the diode demodulator but also a blocking capacitor prior to a resistive volume control. In some cases the volume control forms the resistive part of the diode load but its output is capacitively coupled to the following audio amplifier. In either case the diode sees a different (lower) load for modulating frequencies than it does for the unmodulated signal. A typical schematic illustrating this is shown in Figure 10. The thing we should be concerned about is that in parallel with the diode load (R1-C1) we have an added load which is capacitively coupled to the resistive part of the diode load. The added load is formed by C2 and R2. |
|
The result of adding such an AC load in parallel with the DC load is shown in Figure 11. This waveform is the signal as it appears at the cathode of the diode. |
|
Generally that same signal is applied to a simple R-C lowpass filter the
output of which is used to provide AGC (or "AVC") to the I.F. and perhaps
R.F. amplifier in the receiver.
That load is yet another load that is placed in parallel with the diode's
basic RC network, making the negative-peak clipping situation even worse.
The output of that RC filter is used - perhaps indirectly - to drive a
signal-strength meter.
(In practice the meter measures a direct-current parameter such as
cathode, emitter or source current.)
Notice that the waveform shown in Figure 11 starts at 5 volts and goes up to 10 volts on the positive peaks. On the negative modulation peaks the signal does not go to 0 volts: we have what might be called "carrier shift" because the area under the curve above 5 volts does not equal the area under the curve below 5 volts. It is this phenomena that causes the "S" meter on receivers to move upward with modulation. Of course the clipping as seen here results in audible distortion as well. This situation is caused by the AC load on the diode demodulator; it has nothing to do with diode nonlinearity. Diode nonlinearity will of course make the situation even worse. Collins 51J4 The above analyses used the schematics shown. The topologies along with the parts values shown seem to be very common in the design of the usual radio receiver. Such performance is not unique to low-end radios, however. Even expensive radios such as the Collins 51J4 can suffer from this situation. Shown in Figure 12 is the equivalent circuit used for analysis of that receiver. The input from the B.F.O. is not shown, nor is the cathode follower for the I.F. output, nor is the separate rectifier for AVC purposes. The noise limiter is assumed to be below the clipping threshold. |
|
The output of the diode is shown in Figure 13. |
|
The designers at Collins appeared to choose minimal filtering
(a short time-constant) on the demodulator load.
The allows more RF (I.F., actually) to appear on the positive peaks
and also reduces the slew-rate distortion on the negative peaks.
The modest amount of RF in their case is doubtless of little concern.
The clipping on the negative peaks is certainly an unwelcome surprise. That signal is brought out to the rear of the radio to a test point (labeled "Diode Load") and invites comments about negative-peak clipping. Persons not aware of the demodulator problem under discussion would suppose the clipping is due to overmodulation. The 51J4 also has a buffered I.F. signal output which should be used when critical examination of the modulation is to be made. The selectivity of the radio will of course enter into the picture. The signal-strength meter on the 51J4 does not move with modulation because in that receiver a separate demodulator is used for AVC purposes. The design of the AVC demodulator is such that there is no disparity between the AC and the DC loads. |
|
Slew-rate re-examination
|
|
We have seen the compromise involved with the parallel R-C
load on the demodulator itself. Looking at the diode output,
when the time-constant is too small the amount of RF appearing
on the positive peak increases.
When the time-constant is too large the slew-rate on the
negative modulation peaks becomes noticeable.
This effect is shown in Figure 14.
For this set of plots, three values of time-constant were used
and the plots were overlaid on top of one another.
The waveform illustrating the lowest time-constant is shown in green.
Overlaid on that is the waveform in red, using a higher time-constant.
A third waveform, using an greater time-constant is in black.
As the time-constant is increased the amount of RF appearing on the positive peak is reduced and the slew rate problem is made worse. |
|
AC load problem re-examination The clipping that occurs on the negative modulation peaks can be minimized by making the additional AC load presented to the diode much higher than the basic DC load. The plots shown in Figure 15 illustrate what happens when that AC load is changed in steps. The black plot shows the result when the basic DC load has an AC load of the same value placed in parallel. The blue plot shows the effect of having the AC load changed to twice the value of the DC load. The red plot shows the result when the AC load is 8 times the DC load and finally the green plot shows the result of making the AC load 50 times the DC load (essentially no effect at all). What should be apparent is the necessity of not loading the diode demodulator at all if possible, or using a buffer amplifier between the basic parallel R-C load and any following circuitry. For this series of plots the time-constant on the diode load has been reduced to minimize the slew-rate problem on the negative peaks. As can be seen the byproduct of reducing the time-constant is an increased amount of RF appearing on the positive modulation peaks. |
|
Modulation depth Up to this point only a single modulation depth (100%) has been used. Figure 16 illustrates a series of modulating-signal amplitudes, corresponding to modulation depths of 70%, 80%, 90% and 100%. As before, the waveform shown is actually the idling DC voltage onto which has been added the modulating waveform. It would be what we would like to see at the output of our demodulator. |
|
What we would actually see from the demodulator is then
as shown in Figure 17.
|
|
As the modulation percentage is increased the negative peaks are
suffering from both the slew rate problem and the AC load problem.
|
|
Asymmetric audio waveforms Up to this point only sinusoidal modulating waveforms have been used. A modulating waveform which is asymmetric as viewed on an oscilloscope can yield some unexpected results at the output of a diode demodulator. Figure 18 illustrates a modulating signal using a 1000 Hz sinusoid onto which has been added a 2000 Hz sinusoid. The phase of the 2000 Hz signal has been adjusted to produce that wave. The two sinusoids have the same level. The plot shows the modulating waveform which includes the DC component. |
|
When that waveform amplitude-modulates the carrier the resultant
waveform is shown in Figure 19.
|
|
The output from the demodulator appears would appear as in Figure 20.
|
|
If the polarity or phase of the AC portion of the modulating wave
is inverted then the modulating signal is as shown in Figure 21.
|
|
The resulting modulated signal is shown in Figure 22.
|
|
Thanks to the use of a typical diode demodulator with its slew-rate problem
and its AC load problem the output of the demodulator is as shown in Figure 23.
What we would like to see is shown as the green trace (distortion-free)
and what we actually get is shown in red (with distortion).
|
|
Ye scribe thinks there is surely a moral here.
The most likely recommendation is to make some attempt at minimizing
the possibility of a problem prior to transmission.
Use an allpass system to "scramble" the phases of the dominant components,
or attempt to polarize the signal correctly if it most commonly "points"
in one direction.
In any event, broadcasters shouldn't let the modulation go above 80% (90% absolute maximum) in the negative direction unless they think the listener can tolerate 1 or 2 dB of clipping. Perhaps the listeners are accustomed to such treatment. Negative-peak clipping to prevent the transmitted signal from going to zero amplitude (to allow synchronous demodulation) would have no audible effect on the audio delivered by a typical radio receiver using a diode demodulator. What such negative-peak clipping might do to the audio as delivered by a synchronous detector is outside the scope of this writeup. |
|
General Radio 1931 The General Radio Model 1931 modulation monitor minimizes the problems seen with the above-shown simplistic approaches by application of good design techniques, if perhaps brute-force. Shown in Figure 16 is the equivalent circuit for the circuitry used to recover modulation from the RF input. Separate demodulators are used for metering and for audio monitoring/measuring. They each use remarkably similar techniques to minimize the problems previously pointed out. |
|
Inductor L5 operates in conjunction with resistor R3 to filter out
the residual RF at the output of the demodulator proper.
The DC load on the demodulator is slightly under 50k ohms.
In parallel with R3 is a divider whose value is over 1 megohm in value.
The audio is capacitively coupled by sampling only about 4% of the total
signal; in effect this capacitive (AC) load is decoupled from the demodulator
itself.
Further, the AC load is 1 megohm in parallel with that 40k ohm resistor.
The result is shown in Figure 25.
|
|
This is the signal used to drive the peak-reading voltmeter used to
measure modulation.
There is neither slew-rate limiting nor negative peak clipping.
The residual RF appearing at this point was disturbing to see but
the schematic shows what appears to be a last-minute addition:
a small-value capacitor (C36) bypassing high frequencies (i.e., RF)
to ground from the output of a subsequent modulation-measuring
rectifier-driving amplifier.
This should have been observed earlier on during the original design
effort but the analysis tools available during the initial design of
this monitor (about 1935) were not as convenient as today's.
|
|
Gates M5693 This is the "direct-coupled" monitor manufactured by Gates. This monitor uses a few techniques to reduce the various above-mentioned problems to triviality. One is to use a germanium diode for demodulation, along with quite large signal levels so that the diode forward drop is reduced to insignificance. Gates chose to use separate demodulators for monitoring and for metering. Each of the demodulators has nearly resistive loads on them. Post-detection lowpass filtering is used; both the metering the monitoring demodulators use basically the same topology and component values. |
|
1166 In the schematic, components L1, C5, L2, C6, L3 and C7 form a
lowpass filter to remove the residual carrier from the demodulator
proper.
R4 is the sole load on the filter.
The output from that filter is shown in Figure 27.
|
|
This signal is then applied to an amplifier the output of which
drives the carrier-level and modulation-reading systems.
|
|
Belar AMM-2/3 The Belar analog AM modulation monitors minimize the problems seen above by application of modern design techniques. The slew-rate problem is eliminated by returning the exponential decay of the diode demodulator to a power supply voltage instead of to ground. The negative-peak clipping due to an AC load is eliminated by direct-coupling the output of the post-detection lowpass filter to a buffer amplifier. Extracted from the output of that buffer are the DC component to read carrier level and the AC component to read modulation. An approximation of the Belar analog AM modulation monitor demodulator, reduced to its Spice equivalent, is shown in Figure 26. So that the waveforms shown will have the same polarity (positive) as those presented earlier, the diode polarity and its bias voltage were reversed for analysis from the actual product. |
|
In the schematic, components L1, C5, L2, C6, L3 and C7 form a
lowpass filter to remove the residual carrier from the demodulator
proper.
R4 is the sole load on the filter.
The output from that filter is shown in Figure 27.
|
|
This signal is then applied to an amplifier the output of which
drives the carrier-level and modulation-reading systems.
|
|
To assist those individuals wishing to pursue this subject, some of the Spice netlists used for this paper are shown here. They are generic and will run under LTspice or (with the addition of an output directive) on PSpice and probably on most others. Spice netlists Here is the Spice netlist for the basic diode demodulator. The only load on the diode is a simple shunt R-C.
DIODE TEST 0 .cir
* 28 August 2007 J. Tonne
* Examining slew-rate problem in diode
* demodulator as found in typical
* AM receivers. Ideal (no forward drop)
* diode is used
* Modulated carrier is at node 3.
* Output of diode demodulator proper is
* at node 4.
* Negative-peak clipping can be seen at
* node 4.
Vcarrier 1 0 SIN 0 5 500k
Vaudio 2 0 SIN 1 1 1000
Exmtr 3 0 VALUE = { V(1) * V(2) }
D1 3 4 MyIdealDiode
R1 4 0 100k
C1 4 5 330p
Rhappy 5 0 .1
.MODEL MyIdealDiode D(Ron=0 Roff=1G Vfwd=.0)
.TRAN 1u .003 1u 1u
.END
Here is the Spice netlist for the diode demodulator which has an AC load attached to the basic circuit. This added load causes negative-peak clipping.
DIODE TEST 3 .cir
* 28 August 2007 J. Tonne
* Diode demodulator as found in typical
* low-end AM receivers. Ideal (no forward drop)
* diode is used so negative-peak clipping
* due to DC and AC loadlines not being
* the same can be seen.
* Modulated carrier is at node 3.
* Output of diode demodulator proper is
* at node 4.
* Output of subsequent blocking capacitor is
* at node 6.
* Negative-peak clipping can be seen at
* both node 4 and 6.
Vcarrier 1 0 SIN 0 5 500k
Vaudio 2 0 SIN 1 1 1000
Exmtr 3 0 VALUE = { V(1) * V(2) }
D1 3 4 MyIdealDiode
C1 4 5 .05u
Rfix 5 0 1
R2 4 0 2k
C2 4 6 10u IC=5.105V
R3 6 0 5k
.model MyIdealDiode D(Ron=0 Roff=10Meg Vfwd=.0)
.TRAN 1u .10301 1u 1u UIC
.END
Here is the equivalent circuit for the 51J4.
DIODE TEST 2 .cir
* 28 August 2007 J. Tonne
* Equivalent circuit of demodulator in Collins 51J4
* Ideal (no forward drop) diode is used so
* negative-peak clipping due to DC and AC
* loadlines not being the same can be seen.
* Modulated carrier is at node 3.
* Output of diode demodulator proper is
* at node 4.
* Output to audio amplifier is at node 7
* Negative-peak clipping can be seen at
* nodes 4, 5 and 7.
Vcarrier 1 0 SIN 0 5 500k
Vaudio 2 0 SIN 1 1 1000
Exmtr 3 0 VALUE = { V(1) * V(2) }
D1 3 4 MyIdealDiode
C202 4 8 330p
Rfix 8 0 1
R150 4 5 68k
R151 5 0 33k
R152 4 6 470k
C205c 6 0 .1u IC=+3.27V
R153 6 5 470k
C209 5 7 .01u IC=+1.66V
R154 7 0 500k
.MODEL MyIdealDiode D(Ron=0 Roff=1G Vfwd=.0)
.TRAN 1u .105 1u 1u UIC
.END
Here is the netlist to examine the effect of diode-load time-constant.
DIODE TEST 4 .cir
* 28 August 2007 J. Tonne
* Examining slew-rate problem in diode
* demodulator as found in typical
* AM receivers. Ideal (no forward drop)
* diode is used
* Modulated carrier is at node 3.
* Output of diode demodulator proper is
* at node 4.
* Output of subsequent blocking capacitor is
* at node 6.
* Negative-peak clipping can be seen at
* both node 4 and 6.
Vcarrier 1 0 SIN 0 5 500k
Vaudio 2 0 SIN 1 1 1000
Exmtr 3 0 VALUE = { V(1) * V(2) }
D1 3 4 MyIdealDiode
R1 4 0 100k
C1 4 5 { Cstep }
R2 5 0 .1
.PARAM Cstep=1
.STEP PARAM Cstep LIST 100p 500p 2000p
.model MyIdealDiode D(Ron=0 Roff=1G Vfwd=.0)
.TRAN 1u .003 1u 1u
.END
Here is the netlist to examine the effect of changing the AC load on the demodulator.
DIODE TEST 5 .cir
* 28 August 2007 J. Tonne
* Diode demodulator as found in typical
* low-end AM receivers. Ideal (no forward drop)
* diode is used so negative-peak clipping
* due to DC and AC loadlines not being
* the same can be seen.
* Modulated carrier is at node 3.
* Output of diode demodulator proper is
* at node 4.
* Output of subsequent blocking capacitor is
* at node 6.
* Negative-peak clipping can be seen at
* both node 4 and 6.
Vcarrier 1 0 SIN 0 5 500k
Vaudio 2 0 SIN 1 1 1000
Exmtr 3 0 VALUE = { V(1) * V(2) }
D1 3 4 MyIdealDiode
C1 4 5 .02u
Rfix 5 0 1
R2 4 0 2k
C2 4 6 5u IC=5.105V
R3 6 0 { Rstep }
.PARAM Rstep=1
.STEP PARAM Rstep LIST 2k 4k 16k 100k
.model MyIdealDiode D(Ron=0 Roff=10Meg Vfwd=.0)
.TRAN 1u .10301 1u 1u UIC
.END
Epilog The object of this writeup has been to highlight the problems that are encountered with the ordinary diode demodulator. If the reader is serious about designing a low-distortion demodulator then the hints given along the way should prove useful. The problems can be minimized by attention at the transmission end. Full-screen graphics are easier to understand than the thumbnails in the usual books. Comments and feedback are of course welcome! - Jim Tonne |